1.2.1 Gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie.

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.2.1
2# Parameters:
3# Ontologie: versie 3.0
4# Het gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie in de meetperiode 1 januari t/m 31 december.
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11
12SELECT
13    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Teller)
14    ("Niet van toepassing" AS ?Noemer)
15    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Indicator_FTE36)
16{
17    SELECT 
18        ?maand
19        (SUM(?inzet_uren)/141 AS ?inzet_fte)
20    {
21        BIND("2024-01-01"^^xsd:date AS ?start_periode)
22        BIND("2024-12-31"^^xsd:date AS ?eind_periode)
23
24        ?overeenkomst 
25            a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
26            onz-pers:heeftOpdrachtnemer ?persoon ;
27            onz-g:hasPart ?overeenkomst_afspraak .
28        ?overeenkomst_afspraak
29            a onz-pers:WerkOvereenkomstAfspraak ;
30            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
31            onz-g:startDatum ?start_afspraak .
32        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
33        FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
34
35        ?inzet
36            a onz-pers:GewerktePeriode ;
37            onz-g:definedBy ?overeenkomst ;
38            onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
39            onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
40        BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
41        FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
42        FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
43        BIND(MONTH(?start_inzet) AS ?maand)
44    }
45    GROUP BY ?maand
46}